Build and Application of the Averaged SPICE Model of the Synchronous Buck Module TPS54310

摘要：在Dr. Sam Ben-Yaakov开关电感模型概念的基础上，根据DC-DC模块TPS54310的实际工作原理，建立适用于SPICE软件的等效电路模型，从而可以方便地对TPS54310进行直流分析、小信号分析以及闭环大信号瞬态分析。模型的准确性在所建模型的SPICE仿真结果与TI公司提供的专用设计软件SWIFT™ Designer 2.01的设计结果的对比中得到证实。

关键词：同步整流；开关电感模型；平均SPICE模型；仿真；直流分析；小信号分析；闭环大信号瞬态分析

Abstract Base on the Switched Inductor Model (SIM) concept of Dr. Sam Ben-Yaakov. A averaged SPICE model of the TPS54310 is built using equivalent circuit method.So the DC analysis,small signal analysis and large signal closed loop transient analysis of the TPS54310 can easily be D_ONe.The validity of the model is verified by comparision between the results of design with the original design program SWIFT™ Designer 2.01 and the results of SPICE simulation using the model built in this paper.

Key words synchronous rectifier; Switched Inductor Model; averaged SPICE model; simulation; DC analysis; small signal analysis; large signal closed loop transient analysis

1 引言
自从1978年，R.Keller 首次运用R.D.Middlebrook的理论进行开关电源的SPICE仿真，近30年来，在开关电源的平均SPICE模型的建模方面，许多学者都建立了自己的模型理论，从而形成了各种SPICE模型。这些模型各有所长，比较有代表性的有：Dr. Sam Ben-Yaakov的开关电感模型；Dr. Ray Ridley的模型；基于 Dr. Vatche Vorperian的Orcad9.1的开关电源平均Pspice模型；基于Steven Sandler的ICAP4的开关电源平均Isspice模型；基于Dr. Vincent G. Bello的Cadence的开关电源平均模型等等。本文将在Dr. Sam Ben-Yaakov开关电感模型概念的基础上，结合TI公司的DC-DC变换器IC TPS54310的主要参数进行平均SPICE宏模型的构建，并对利用所建模型构成的DC-DC变换器电路在Intusoft公司的ICAP4软件平台上进行直流分析、小信号分析以及闭环大信号瞬态分析。

2 TPS54310的平均SPICE模型的建立
TPS54310是美国TI公司推出的集成功率MOSFET的直流/直流变换器IC系列SWIFT的新成员，3V 至 6V输入，0.9V 到 3.3V可调输出，连续额定电流达3A。TPS54310集成了构成同步整流BUCK型DC-DC模块所有需要的有源器件， 内部电路框图见（图1）。

（图1）TPS54310内部电路框图

主电路模型的构建
主电路模型包括开关电感SIM模型、占空比发生器DCG以及损耗发生器模型三部分。

1. 开关电感SIM模型
仔细研究经典PWM开关转换器的电路拓扑（buck，boost,buck-boost），可以发现它们均包含一个非线性模块，即用来储能的可开关的电感，见（图2）。因为变换器的系统带宽要小于开关频率，因此可以把这个非线性模块作平均处理，然后用与SPICE兼容的等效电路代替，就可以得到PWM开关转换器的平均SPICE模型。这个低频的或者平均的等效电路见（图3），用SPICE中的非线性独立源构成。EL代表储能电感L两端的平均电压。

   (1)

流过开关电感各端口的平均电流如下：

   （2a） I_L代表流过储能电感L的平均电流

（图3）开关电感模型

（图2）开关电感

（1） 式和（2a）~ （2c）式的关系适用于CCM连续电感电流和DCM不连续电感电流两种工作模式。

2. 占空比发生器DCG
TPS54310内部采用电压模式的脉宽调制器，PWM比较器把误差放大器输出的控制电压与振荡器产生的锯齿波电压进行比较以产生所需的接通占空比D_ON，如（图4）所示。查TPS54310数据手册中的关键特性参数表可得， VL=0.75V，VH=1.75V，所以

（图4）

（图5）

对应（3）式的等效模型见（图5），X1是增益为1的增益宏模型，可从ICAP4的模型库里直接调用。断开占空比D_OFF的产生比较复杂，分为下面两种情况：

DCM模式

CCM模式

对应（4）式和（5）式的等效模型见（图6）。其中，非线性独立电压源ED_OFF对应（4）式

（图6）

在CCM模式下，D_OFF≥1-D_ON，理想二极管D2导通，这时，

可以看出，D_OFF发生器模型在DC-DC转换器进入CCM模式和DCM模式时是自适应的，在仿真过程中无需人工切换。理想二极管D1的作用是确保D_OFF不小于0。

3. 损耗发生器模型
TPS54310 DC-DC转换器的损耗主要有三部分：整流损耗、高频开关损耗和储能电感的平均欧姆损耗。整流损耗模型用一个非线性独立电流源和TPS54310内部的同步整流管模型构成；高频开关损耗模型用一个非线性独立电流源和TPS54310内部的高频开关管的导通电阻构成；储能电感的平均欧姆损耗模型用一个非线性独立电流源和TPS54310外接储能电感的欧姆电阻构成。

误差放大器宏模型的构建

误差放大器的电路级模型厂家一般不公布，这里根据TPS54310的数据手册，建立误差放大器的性能模型。由于性能模型采用黑箱模拟，因而降低了模型的复杂度，同时获得了更高的仿真效率。建立TPS54310误差放大器的性能模型需要下面6个主要参数：
1. 直流开环增益：120dB 或1000000 {GAIN}
2. 第一极点：3.75Hz {POLE}
3. 最大输出电压：1.75V {VHIGH}
4. 最小输出电压：0.75 V{VLOW}
5. 最大吸电流：3mA {ISINK}
6. 最大源电流：3mA {ISOURCE}

直流开环增益和第一极点的数据来自TPS54310数据手册中的误差放大器开环频响曲线。

最大输出电压和最小输出电压结合上面的（3）式推出。即当D_ON=0，误差放大器输出最小控制电压0.75V；当D_ON=1，误差放大器输出最大控制电压1.75V。最终TPS54310误差放大器的宏模型见（图7），其开环仿真曲线见图（8）。

（图7）TPS54310误差放大器的宏模型

（图8）TPS54310误差放大器的开环仿真曲线

同步整流管模型的构建
TPS54310同步整流管模型简化地用具有更小正向电压降的肖特基二极管来模拟。对理想二极管，正向电压降的公式：

（图9）同步整流管模型的I-V仿真特性曲线

一般用增大饱和电流IS的办法建立肖特基二极管的模型。用ICAP4软件包中的模型提取工具 SpiceMod，可以快速地建立同步整流管模型，如下： .MODEL D_SYNC D (IS=3.99M RS=2.8M N=1 CJO=10P VJ=0.75 M=0.333 TT=1.0N)。

（图9）是仿真的同步整流管模型I-V特性曲线。

可以看出，当电流为3A时，正向电压降为0.18V。

这个结果与TPS54310的同步整流管在3A时的压降3*0.059=0.177V是吻合的。

最终建立的TPS54310的平均SPICE模型内部电路见（图10），（图11）是对应的宏模型块的符号，供画仿真电路图时调用。定义的6个管脚除VERR外，都与TPS54310的实际管脚一致。管脚VERR用来在开环交流小信号仿真时插入交流信号源。TPS54310的模型需输入四个参数：开关频率FS，储能电感值L，储能电感的欧姆电阻RS，高频开关管的导通电阻RON。完整的TPS54310模型的SPICE网络文件见附件。

（图11）TPS54310宏模型块符号

3 TPS54310的平均SPICE模型的验证与应用
为了验证模型的正确性，用TI公司提供的专用设计软件SWIFT™ Designer 2.01设计了五种DC-DC变换电路，然后利用前面所建的TPS54310模型，构成同样的DC-DC变换器的仿真电路，在ICAP4软件上进行直流分析和交流小信号分析，比较这两种方法获得的数据，见（表1）。可以看出，二者的差别非常小。因此有理由认为，TPS54310的平均SPICE模型是可信的。

（图10）TPS54310的平均SPICE模型内部电路

表一

（图12）TPS54310演示板直流和交流小信号仿真电路

（图13）

（图15）负载瞬态响应仿真波形

（图16）输入音频扰动衰减率与频率的关系曲线

（图14）TPS54310演示板负载瞬态响应和输入音频扰动衰减率仿真电路

下面，利用前面所建的TPS54310平均 SPICE模型对TI公司提供的演示板电路进行全面的仿真分析。直流和交流小信号分析的仿真电路见（图12），直流工作点标注在图上。得到的系统的开环频率特性（幅频和相频）见（图 13）。环路增益交越频率为44KHz，过0dB 时，相移为83.1度，证明该电源系统是稳定的。（图14）是仿真负载瞬态响应和输入音频扰动衰减率的电路图。注意仿真技巧，C3 由（图12）的1kF变为1pF,相当于交流开路节点8和4；同时，L1 由（图12）的1gH变为1pH,相当于交流短路节点8和5，形成闭环。分段线性源ILoad模拟负载电流的瞬间突变（在1us内跳变3A）。（图15）是负载瞬态响应波形。在电源输入端插入1Vac 的交流电压源，在节点9得到如（图16）所示的输入音频扰动衰减率与频率的关系曲线，反映了系统对小信号正弦波输入电压扰动的抑制能力。为了研究系统对负载扰动的抑制能力，在输入音频扰动衰减率与频率的关系曲线负载瞬态响应仿真波形输出端插入1Aac的交流电流源（仿真电路略），在节点9可得到闭环输出阻抗，见（图17）。至此，采用所建的TPS54310平均SPICE模型已对TI公司提供的演示板电路进行了较全面的动态指标的仿真分析，包括稳定性，快速性和抗扰动性，这是TI的设计软件SWIFT™ Designer 2.01所不能给出的。

（图17）闭环输出阻抗与频率的关系曲线

4. 总结
建立TPS54310平均SPICE模型的意义在于，只需要厂家公开的电源IC的技术资料，就能提取具有相当准确度的模型，方便设计者在制作出实际的电路之前，对电源的性能，特别是动态性能做出全面的评估，从而指导设计者对电源进行优化。而且比起开关模型来说，占用机时少，有很高的仿真效率。对比厂家给出的原始设计软件，运用平均SPICE模型在通用电路分析软件上仿真更灵活，更强大，应该是原始设计软件必不可少的补充。

TPS54310平均SPICE模型建立了同步整流BUCK型DC-DC模块平均SPICE模型的通用电路框架，具有一定的普遍性。稍微调整几个模型参数，就可以建立TI公司整个SWIFT电源IC家族的模型，如TPS54610，TPS54810，TPS54672等等。对其他厂家的电源IC产品，通过适当修改也可以方便地建立它们的平均SPICE模型。

附件
TPS54310模型的SPICE网络文件：
* TPS54310 model developed by He Yaning,Chengdu (China)
* The model automatically toggle between DCM and CCM
* INTUSOFT's IsSpice4 compatible
* Last modified: June 5th 2002
* SRC=TPS54310;TPS54310;PWM Models;TI;DC-DC module
* SYM=TPS54310_NEW
.SUBCKT TPS54310 IN OUT VSENSE GND COMP VERR { FS=??? L=??? RS=??? RON=??? }
BGIND GND VRIND I=I(VLM)/(V(DON)+V(DOFF)+1u)
RIND VRIND GND {RS}
BGSW GND VSW I=I(VLM)/(V(DON)+V(DOFF)+1u)
RSW VSW GND {RON}
BERDS Z2 GND V=V(K)
BGB GND Z2 I=V(DOFF)*I(VLM)/(V(DON)+V(DOFF)+1u)
BGD K GND I=I(VLM)/(V(DON)+V(DOFF)+1u) ; OFF Averaged diode losses
VCLP VC GND DC=9m
X2 23 DON GAIN { K=1 }
.SUBCKT GAIN 1 2 {K=???}
*Connections: In Out
*Parameters: K Gain
E1 2 0 1 0 {K}
.ENDS
BGA Z1 GND I=I(VLM)*V(DON)/(V(DON)+V(DOFF)+1u)
BVSW IN Z1 V=V(VSW)
BDOFFM 6 GND V=1-V(DON)-9M
BELM OUT1 GND V=V(DON)*V(Z1,C)+V(DOFF)*V(Z2,C)
RM OUT1 5 10m
LM 5 8 {L}
VLM 8 GND
D1 GND K D_SYNC
.MODEL D_SYNC D (CJO=10P IS=3.99M M=0.333 N=1 RS=2.8M
+ TT=1.0N VJ=0.75)
BDOFF 7 GND V=2*I(VLM)*{L}/({1/FS}*(V(Z1)-V(C))*V(DON)+1u)-V(DON)
R4 DOFF 7 10
BGC GND C I=I(VLM)
BIND C OUT V=V(VRIND)
D3 VC DOFF DBREAK
D4 DOFF 6 DBREAK
.MODEL DBREAK D (TT=1N CJO=10P N=0.01)
V3 17 GND DC=0.891
V4 VERR 23 DC=0.75
X1 17 VSENSE COMP GND TPS54X { }
.SUBCKT TPS54X 20 8 3 21 {GAIN=1e6 POLE1=3.75 VHIGH=1.75 VLOW=0.75 ISINK=3m ISOURCE=3m}
* + - OUT GND
RIN 20 8 8MEG
CP1 11 21 {1/(6.28*(GAIN/100U)*POLE1)} ; pole1 calculation
E1 5 21 11 21 1
R9 5 2 1
CP2 2 21 500P
l1 2 30 1uH
CP3 30 21 190P
R6 30 21 210
D14 30 13 DMOD
IS 13 21 {ISINK/100} ; sink limit, with BF=100
Q1 21 13 16 QPMOD
ISOURCE 7 3 {ISOURCE} ; source limit
D12 3 7 DMOD
D15 21 11 DCLAMP
G1 21 11 20 8 100U
V1 7 21 {VHIGH-0.68} ; max output clipping
V4 3 16 {VLOW-0.238} ; min output clipping
RP1 11 21 {GAIN/100U} ; open loop gain calculation
.MODEL QPMOD PNP
.MODEL DCLAMP D (RS=10 BV=2.8 IBV=0.01)
.MODEL DMOD D (TT=1N CJO=10P)
.ENDS
*$
.ENDS